.TITLE	INICRA
	.IDENT	/3.00/

; Copyright (c) 1995-1999 by Mentec, Inc., U.S.A.
; All rights reserved
;

;
;	J. WEHNER  06-MAY-83
;
;	LOADABLE CRASH INITIALIZATION MODULE
;
; PREVIOUSLY MODIFIED BY:
;
;	J. G. WEHNER
;	J. W. BERZLE
;	G. N. LARSEN
;	P. K. M. WEISS
;
; MODIFIED FOR RSX-11M-PLUS V4.3 - VAX COPROCESSOR/RSX V2.0 BY:
;
;	K. L. NOEL		19-JUL-89		V3.00
;
;		KLN138 -- VECTOR SYMBOLS FOR NETWORK LOADABLE CRASH DRIVERS
;

;


;***********************
;
; THE FOLLOWING IS A TRANSFER WORD WHICH MUST BE THE FIRST LOCATION OF
; THIS MODULE.  WHEN A CRASH OCCURS, A JUMP IS MADE INDIRECT THROUGH THIS
; LOCATION TO BYPASS THE EXP INITIALIZATION ROUTINES.
;

	.WORD	TRNSFR		
;***********************


	.MCALL	DIR$,GIN$
;
; EXEC ENTRY VECTOR TABLE
;
EXEVEC:
	.WORD	0
BCBUF:: .WORD	$BCBUF
CRALT::	.WORD	$CRALT
CRBAE::	.WORD	$CRBAE
CRCSR::	.WORD	$CRCSR
CRDEV::	.WORD	$CRDEV
CRDV1::	.WORD	$CRDEV
CRKRB::	.WORD	$CRKRB
CRMS0::	.WORD	$CRMS0
CRMS3::	.WORD	$CRMS3
CRMS6::	.WORD	$CRMS6
CRPAR::	.WORD	$CRPAR
CRSBN::	.WORD	$CRSBN
CRSB2::	.WORD	$CRSBN
CRSCS::	.WORD	$CRSCS
CRSFM::	.WORD	$CRSFM
CRSUN::	.WORD	$CRSUN
CRUNT::	.WORD	$CRUNT
HFMSK::	.WORD	$HFMSK
KISA5::	.WORD	KISAR5
KISA6::	.WORD	KISAR6
MSCR1::	.WORD	$MSCR1
MSCR2::	.WORD	$MSCR2
MSCR3::	.WORD	$MSCR3
UISA6::	.WORD	UISAR6
SYSIZ:: .WORD   $SYSIZ

EXEVCL=<<.-EXEVEC>/2>

TRNVEC:	GIN$	GI.VEC,EXEVEC,EXEVCL ; TRANSLATE EXECUTIVE VECTOR

;
; INITIALIZE CRASH DATA BASE 
;

$XPLOA::
	MOV	PC,R0			; MAKE CODE PIC
	ADD	#TRNVEC-.,R0		; RELOCATED ADDR OF DPB
	MOV	PC,R1			
	ADD	#EXEVEC-.,R1
	MOV	R1,4(R0)		; RELOCATE EXEVEC ADDR IN DPB
	DIR$	R0			; TRANSLATE EXECUTIVE VECTOR
	BCC	5$
	BPT

5$:
	ADD	#2,CRSB2		; MAKE THIS $CRSBN+2
	INC	CRDV1			; MAKE THIS $CRDEV+1
	CALL	$SWSTK,10$		; GO TO SYSTEM STATE
	MOV	PC,R0			;; CALCULATE RETURN ADDRESS
	ADD	#10$-.,R0
	MOV	R0,16(SP)		;; SET RETURN ADDRESS
	MOV	@UISA6,@CRPAR		;; STORE THE PARTITION LOAD ADDRESS
	MOV	#PBNH,@CRSBN		;; STARTING BLOCK NUMBER
	MOV	#PBNL,@CRSB2
	MOV	#PBNH,@CRSCS		;; SBN CHECK SUM
	ADD	#PBNL,@CRSCS

10$:	RETURN 				;; BACK TO USER STATE

;
; CLR DATA BASE BEFORE UNLOADING THE PARTITION
;

$XPUNL::
	CALL	$SWSTK,10$		; GO TO SYSTEM STATE
	MOV	PC,R0			;; CALCULATE RETURN ADDRESS
	ADD	#10$-.,R0
	MOV	R0,16(SP)		;; SET RETURN ADDRESS
	CLRB	@CRDEV			;; CLEAR THE DEVICE NAME
	CLRB	@CRDV1
	CLR	@CRSUN			;; CLEAR THE DEVICE UNIT NUMBER
	CLRB	@CRUNT			;; CLEAR THE ASCII DEVICE NUMBER
	CLR	@CRCSR			;; CLEAR THE DEVICE CSR
	CLR	@CRSCS			;; CLEAR THE CHECK SUM
	CLR	@CRPAR			;; CLEAR PARTITION ADDRESS
	CLR	@CRKRB			;; CLEAR THE KRB
10$:	RETURN				;; BACK TO USER STATE

TRNSFR:
	.END